blog.ijacek007.cz

Chtěli jste mít někdy přehled o teplotě v blízkosti Vaší bezdrátové sítě? Dnes Vám ukáži, jak si můžete udělat teploměr s vlhkoměrem přístupný na vaší síti, který nestojí ani 200 korun.

Budete potřebovat pouze modul ESP8266, který lze na ebay pořídit okolo 50 kč. Poté teploměr s vlhkoměrem, který stojí okolo 80 kč. Dále něco čím, to vše budeme napájet, takže zdroj 3,3V. Ten by měl mít více jak 500mA. Modul toho sice moc nespotřebuje nicméně při zobrazení informací pomocí vnitřního serveru, může docházet k větším požadavkům na spotřebu. Uváděná zátěž ve špičce je okolo 400 mA. V mém příkladu jsem ještě použil dvoubarevnou diodu, pomocí které zobrazuji, zda je modul připojen k Wi-Fi.

Diody jsem tam přidal ze dvou důvodu. Jednak abych si vyzkoušel a trochu osvojil práci s výstupy tohoto modulu a také abych měl okamžitý přehled, zda-li je čidlo připojené k bezdrátové síti. Za předpokladu, že budete mít čidel více, je dioda rozsvícena při správném připojení, nepostradatelný pomocník.

/* DHTServer - ESP8266 Webserver with a DHT sensor as an input

   Based on ESP8266Webserver, DHTexample, and BlinkWithoutDelay (thank you)

   Version 1.0  5/3/2014  Version 1.0   Mike Barela for Adafruit Industries
*/

#include <ESP8266WiFi.h>
#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <DHT.h>
#define DHTTYPE DHT22
#define DHTPIN  2
#define led_wifi_ok  4
#define led_wifi_ko  5

const char* ssid     = "moje tajna wifi";
const char* password = "Super tajné heslo";


ESP8266WebServer server(80);

// Initialize DHT sensor
// NOTE: For working with a faster than ATmega328p 16 MHz Arduino chip, like an ESP8266,
// you need to increase the threshold for cycle counts considered a 1 or 0.
// You can do this by passing a 3rd parameter for this threshold.  It's a bit
// of fiddling to find the right value, but in general the faster the CPU the
// higher the value.  The default for a 16mhz AVR is a value of 6.  For an
// Arduino Due that runs at 84mhz a value of 30 works.
// This is for the ESP8266 processor on ESP-01
DHT dht(DHTPIN, DHTTYPE, 22); // 11 works fine for ESP8266

float humidity, temp_f;  // Values read from sensor
String webString="";     // String to display
// Generally, you should use "unsigned long" for variables that hold time
unsigned long previousMillis = 0;        // will store last temp was read
const long interval = 2000;              // interval at which to read sensor

void handle_root() {
 // server.send(200, "text/plain", "Hello from the weather esp8266, read from /temp or /humidity");
   gettemperature();       // read sensor
    webString="Teplota:"+String(temp_f)+"C | Vlhkost:"+String((int)humidity)+"%";
// Arduino has a hard time with float to string
    server.send(200, "text/plain", webString);            // send to someones browser when asked

  delay(100);
}

void setup(void)
{

  // Nastav pin obou diod na  zapis a nastav nizkou hodnotu (LED dioda nesviti)
 pinMode(led_wifi_ok, OUTPUT);
 digitalWrite(led_wifi_ok, LOW);

 pinMode(led_wifi_ko, OUTPUT);
 digitalWrite(led_wifi_ko, LOW);

  // You can open the Arduino IDE Serial Monitor window to see what the code is doing
  Serial.begin(115200);  // Serial connection from ESP-01 via 3.3v console cable
  dht.begin();           // initialize temperature sensor

  // Connect to WiFi network
  WiFi.begin(ssid, password);
  Serial.print("\n\r \n\rWorking to connect");

  // Wait for connection
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  Serial.println("");
  Serial.println("DHT Weather Reading Server");
  Serial.print("Connected to ");
  Serial.println(ssid);
  Serial.print("IP address: ");
  Serial.println(WiFi.localIP());

  server.on("/", handle_root);


  server.begin();
  Serial.println("HTTP server started");
}

void loop(void)
{
  server.handleClient();

 if (WiFi.status() == WL_CONNECTED) {  digitalWrite(led_wifi_ok, HIGH);digitalWrite(led_wifi_ko, LOW);   }
 if (WiFi.status() == WL_DISCONNECTED) {digitalWrite(led_wifi_ok, LOW);digitalWrite(led_wifi_ko, HIGH);}

}

void gettemperature() {
  // Wait at least 2 seconds seconds between measurements.
  // if the difference between the current time and last time you read
  // the sensor is bigger than the interval you set, read the sensor
  // Works better than delay for things happening elsewhere also
  unsigned long currentMillis = millis();

  if(currentMillis - previousMillis >= interval) {
    // save the last time you read the sensor
    previousMillis = currentMillis;

    // Reading temperature for humidity takes about 250 milliseconds!
    // Sensor readings may also be up to 2 seconds 'old' (it's a very slow sensor)
    humidity = dht.readHumidity();          // Read humidity (percent)
    temp_f = dht.readTemperature();     // Read temperature as Fahrenheit
    //float t = dht.readTemperature();
    // Check if any reads failed and exit early (to try again).
    if (isnan(humidity) || isnan(temp_f)) {
      Serial.println("Failed to read from DHT sensor!");
      return;
    }
  }
}

Příklad jsem jen mírně upravil od funkčního systému z internetu. Nejvíce mi trvalo, než jsem přišel, kde autor originálu udělal úpravu, aby se z čidla odečítaly pouze celá čísla. U vlhkosti je to v celku jedno, nicméně jsem chtěl, aby zobrazení teplot bylo i s desetinou čárkou, aby bylo hned na první pohled jasné, kam se teplota pohybuje.

Výsledkem je minimalistická stránka, která zobrazuje pouze požadované hodnoty a na diodě připojené k modulu hned vidíte, zda je modul připojený k bezdrátové síti.

Mohlo by Vás zajímat

Reálné zapojení ESP8266 a trojice teploměru s vypnutou funkcí AP

První zapojení ESP8266 na desce esp07

Originální příklad z něhož jsem vycházel (anglicky)

Stránky popisující možnosti WiFi Status(u) web arduino (anglicky)

programovani | recenze | skutecnost | stavebnice |
Autor Ijacek.007 27.10.2016 zobrazeno 11 161x První zapojení ESP8266 na desce esp07
Wi-Fi teploměr s esp8266 se třemi čidly dht22 a regulaci svitu diody